#!/bin/csh -f

echo -n "Enter Name of function curve : "
set name=($<)
set name_e = $name:e
if ($name_e != "fraw") then
	set name = "$name.fraw"
endif
if (! -e $name ) then
	echo "No function curve: $name"
	exit -1
endif
echo
echo "Enter a Command Line, specifying with ## where the"
echo "function curve values are to be inserted."
echo
echo "Example: composite output -s 1 30 1 layer0 layer1 -f ##"
echo
echo -n "Enter Command Line : "
set input=($<)
set numbers = `cat $name|awk '{printf("%f\n",$2)}'`
set num_lines = `cat $name|wc -l`

set params = `echo $input`
loop:
switch ("${params[1]}")
	case -s:	
		breaksw
	default:
		if ($#params == 1) then
			echo "ERROR: Must have -s option"
			exit -1
		endif
		shift params
		goto loop
endsw

if ($#params <= "3") then
	echo "ERROR: -s needs 3 values."
	exit -1
endif

shift params
set start = ${params[1]}
set end = ${params[2]}
set step = ${params[3]}
set newval = $start

shift numbers
shift numbers

while ($#numbers > 0)
	set new = `echo $input|sed "s/##/${numbers[1]}/"|sed "s/-s $start $end $step/-s $newval $newval 1/"`
	echo $new
	$new
	@ newval = $newval + $step
	if ($newval > $end) then
		exit 1
	endif
	shift numbers
end
@ endval = $newval - $step
if ($endval != $end) then
	echo "Sorry, ran out of data."
endif
