#!/bin/csh -f
#
#       %W% %E%
#
# called to check whether a frame is ready
# 
# takes aniname frameno project pid_fil   
#
# WARNING  do NOT echo in this script for debugging
# before the echo of retval

set host = `uname -n`
set curf = curf_${host}
set rendir = ${GIG_D_ROOT}/projects/renmanadm/${curf}

set aniname = $1
set frameno = $2
set project = $3
set proddir = ${GIG_D_ROOT}/projects/${project}_prj/production/

if ($frameno < 10) then
  set noext = "000"$frameno
else if ($frameno < 100) then
  set noext = "00"$frameno
else if ($frameno < 1000) then
  set noext = "0"$frameno
else
  set noext = $frameno
endif

set todo = `showtiff -vT ${proddir}${aniname}${noext}".tif" |& grep "Image Width:" | awk '{print $6}'`
set done = `showtiff -vT ${proddir}${aniname}${noext}".tif" |& grep "line" | fgrep -v not | awk '{print $4}'`

set ret_val = ''

if ( ( $todo != "" ) && ( $done != "" ) ) then
  if ($todo == $done) then
# a sleep prevents missing timing
    sleep 5
    set jout = ${rendir}/${aniname}${frameno}${project}.out
    set jint = ${rendir}/${aniname}${frameno}${project}.int
    set rtim = `cat $jout | grep "$aniname" | awk '{print $12}'`
    set ret_val = ("done "${rtim})
    /bin/rm $jout
    /bin/rm $jint
  else
    set ret_val = "notfinished"
  endif
else
  set ret_val = "notfinished"
endif

echo $ret_val
