#!/bin/csh -f
#
#       %W% %E%
#

set host = `uname -n`
set curf = curf_${host}
set rendir = ${GIG_D_ROOT}/projects/renmanadm/${curf}
set rendirnodef = ${rendir}/current_nodes
set rendirjobsf = ${rendir}/running_jobs

set n_entrs = `cat $rendirnodef | awk 'BEGIN {} {s+=1;} END {print s}' s=0 -`
set k = 0

while ( $k < $n_entrs )

  set get_nod = `cat $rendirnodef | awk 'BEGIN{}{if(s==t){print $0;exit};s+=1;}END{}' s=0 t=$k -`

  if ( $get_nod[1] != 'idle' ) then

    set get_job = `grep "$get_nod[2] $get_nod[3]" $rendirjobsf`
    shift get_job
    shift get_job
    shift get_job
    set arguments = `getopt vr:i:o:idp: $get_job`

#  get project aniname and frameno
    foreach i ( $arguments )
      switch ( $i )
        case '-d'
          shift arguments
          breaksw
        case '-v'
          shift arguments
          breaksw
        case '-V'
          shift arguments
          breaksw
        case '-r'
          shift arguments
          shift arguments
          breaksw
        case '-o'
          shift arguments
          shift arguments
          breaksw
        case '-p'
          set project = $arguments[2]
          shift arguments
          shift arguments
          breaksw
        case '-i'
          shift arguments
          shift arguments
          breaksw
        case '--'
          shift arguments
          break
      endsw
    end

    set aniname  = $arguments[1]
    set frameno  = $arguments[2]
  
    if ($frameno < 10) then
      set noext = "000"$frameno
    else if ($frameno < 100) then
      set noext = "00"$frameno
    else if ($frameno < 1000) then
      set noext = "0"$frameno
    else
      set noext = $frameno
    endif

    set proddir = $GIG_D_ROOT"/projects/"$project"_prj/production/"

    set todo = `showtiff -vT ${proddir}${aniname}${noext}".tif" |& grep "Image Width:" | awk '{print $6}'`
    set done = `showtiff -vT ${proddir}${aniname}${noext}".tif" |& grep "line" | fgrep -v not | awk '{print $4}'`

    if ( $#get_nod > 4 ) then
      if ( $done != '' && $todo != '' ) then
        echo $get_nod[2] $get_nod[1] $project $aniname $frameno line $done of $todo '  ' renderhours $get_nod[5] - $get_nod[6]
      else
        echo $get_nod[2] $get_nod[1] $project $aniname $frameno just started '  ' renderhours $get_nod[5] - $get_nod[6]
      endif
    else
      if ( $done != '' && $todo != '' ) then
        echo $get_nod[2] $get_nod[1] $project $aniname $frameno line $done of $todo
      else
        echo $get_nod[2] $get_nod[1] $project $aniname $frameno just started
      endif
    endif

  else

    if ( $#get_nod > 4 ) then
      echo $get_nod[2] $get_nod[1] '  ' renderhours $get_nod[5] - $get_nod[6]
    else
      echo $get_nod[2] $get_nod[1]
    endif
  endif

  @ k += 1

end
