#!/bin/csh -f
#
# systemreport
#
# When sending a bugreport to electrogig, please include
# the output of this script.
#
# @(#)systemreport	1.1 96/10/04
#
#


switch(`uname -m`)
   case IP[0-9]:
   case IP[0-9][0-9]:
   case IP[0-9][0-9][0-9]:
      set m = sgi
      breaksw
   case MIPS:
   case RISC:
      set m = dec
      breaksw
   case sun:
   case sun4:
   case sun4[a-z0-9]:
      set m = sun
      breaksw
   case 9000/[0-9][0-9][0-9]:
      set m = hp
      breaksw
   case i986:
   case i886:
   case i786:
   case i686:
   case i586:
   case i486:
   case i386:
      set m = linux
      breaksw
   default:
      echo unknown machine
      exit 1
endsw

echo ============================================================
echo SYSTEM INFORMATION GATHERED FOR A BUG REPORT TO ELECTROGIG
echo -n DATE: 
date
$BD/gig -V
echo ============================================================
echo


###################
# SGI
###################
if ( $m == sgi ) then
  echo 
  echo HOSTINFO
  echo ------------------------------------------------------------
  uname -a
  echo 
  echo HARDWARE INVENTORY
  echo ------------------------------------------------------------
  hinv
  echo 
  echo BINARIES INFO
  echo ------------------------------------------------------------
  ls -al $BD/gig
  file $BD/gig
  elfdump -Dl $BD/gig 
endif



###################
# SUN
###################
if ( $m == sun ) then
  echo
  echo HOSTINFO
  echo ------------------------------------------------------------
  uname -a
  dmesg

  echo 
  echo BINARIES INFO
  echo ------------------------------------------------------------
  ls -al $BD/gig
  file $BD/gig
endif


###################
# HP
###################
if ( $m == hp ) then
  echo ""
  echo HOSTINFO
  echo ------------------------------------------------------------
  uname -a

  echo ""
  echo LIBRARIES INFO
  echo ------------------------------------------------------------
  what /usr/lib/pa1.1/libcl.sl \
       /usr/lib/PEX5/cge_utilities/libPEXUt.sl \
       /usr/lib/libPEX5.sl \
       /usr/lib/X11R5/libXt.sl \
       /usr/lib/X11R5/libX11.sl \
       /lib/libc.sl

  echo ""
  echo GRAPHICS INFO
  echo ------------------------------------------------------------
  /usr/bin/graphinfo

  echo ""
  echo BINARIES INFO
  echo ------------------------------------------------------------
  ls -al $BD/gig
  file $BD/gig
  chatr ~gig/bin/gig

endif


###################
# LINUX
###################
if ( $m == linux ) then
  echo 
  echo HOSTINFO
  echo ------------------------------------------------------------
  uname -a
  cat /proc/cpuinfo
  cat /proc/meminfo
  echo 
  echo NETWORK INFO
  echo ------------------------------------------------------------
  /sbin/ifconfig eth0
  echo 
  echo BINARIES INFO
  echo ------------------------------------------------------------
  ls -al $BD/gig
  file $BD/gig
  ldd $BD/gig
endif



