#!/bin/csh -f 
#
#******************************************************************************
# $Source: /vobs/develop/src/environment/INSTALL_LICENCE,v $
#
# Inferno/Flame/Flint licence file script.
#
# Last Modification: $Revision: 1.0 $
#                    $Date: 1996/02/03 18:17:11 $
#
# Copyright (c) 1996 Discreet Logic, Inc.
#******************************************************************************

#***************************************************************************
# Create the licence file.
#***************************************************************************
set TMPFILE = "/usr/local/flexlm/licenses/.__tmp__lsfile__"
set LSFILE = "/usr/local/flexlm/licenses/DL_license.dat"

set VERFILE = `ls -1d *_VERSION`

set PRODBASE = `echo $VERFILE | nawk -F_ '{ printf "%s", tolower( $1 )}'`
set PRODVER = `cat $VERFILE | nawk '{  gsub( "\"", "", $3 ); print $3 }'| cut -c1`
set PRODUCT = `echo $PRODBASE $PRODVER | nawk '{ printf "%s%s", $1,$2}'`

set LICENCESTR = "DAEMON discreet_l \nFEATURE ${PRODUCT} discreet_l ${PRODVER}.999 1-jan-0 0 0 HOSTID=0 ck=0\n"
set LICENCESTR2 = "FEATURE ${PRODUCT} discreet_l ${PRODVER}.999 1-jan-0 0 0 HOSTID=0 ck=0\n"

if( ! $#VERFILE ) then
  echo $0\: ERROR\: Cannot locate version file \(e.g, FLAME_VERSION\). Install aborted
  exit 1
else if ( $#VERFILE > 1 ) then
  echo $0\: ERROR\: too many version files\!. Install aborted
  exit 1
endif


if ( ! -e $LSFILE ) then
  if ( ! -d $LSFILE:h ) then
    mkdir -p $LSFILE:h
    if ( $status ) then
	echo $0\: ERROR\: failed to create $lsfile
	exit 1
    endif
  endif
  echo $LICENCESTR > $LSFILE
else if ( `egrep -c $PRODUCT $LSFILE` == 0 ) then
  echo $LICENCESTR2 >> $LSFILE
endif

echo "########################################################################"
echo "#                                                                      #"
echo "#          Do you have your Discreet Logic Licence Form (Y/N)?         #"
echo "#                                                                      #"
echo "########################################################################"
echo

set YESNO = $<
if ( `echo $YESNO | nawk -F_ '{ printf "%s", tolower( $1 )}'` == "n" ) then
   exit 1
endif

echo "########################################################################"
echo "#                                                                      #"
echo "#    Be sure to enter the information exactly as it appears on your    #"
echo "#                    Discreet Logic Licence Form                       #"
echo "#                                                                      #"
echo "########################################################################"
echo

set YESNO="n"
while ( `echo $YESNO | nawk -F_ '{ printf "%s", tolower( $1 )}'` != "y" ) 
   echo "Please enter Expiry Date ( e.g. 1-jan-0 ):"
   set EXPIRE = $<
   echo "You entered ${EXPIRE}, is this correct (Y/N)?"
   set YESNO = $<
end 

set YESNO="n"
while ( `echo $YESNO | nawk -F_ '{ printf "%s", tolower( $1 )}'` != "y" ) 
   echo "Please enter Licence Code:"
   set CODE = $<
   echo "You entered ${CODE}, is this correct (Y/N)?"
   set YESNO = $<
end 

set YESNO="n"
while ( `echo $YESNO | nawk -F_ '{ printf "%s", tolower( $1 )}'` != "y" ) 
   echo "Please enter Check Sum:"
   set CHKSUM = $<
   echo "You entered ${CHKSUM}, is this correct (Y/N)?"
   set YESNO = $<
end 


set TMPID = `sysinfo -s`
set HOSTID = `echo $TMPID 16o p | dc`

if ( -e $TMPFILE ) then
  rm -f $TMPFILE
endif

cat $LSFILE | \
  nawk -v product=$PRODUCT -v prodver=$PRODVER -v expire=$EXPIRE -v code=$CODE -v prodbase=$PRODBASE \
       -v hostid=$HOSTID -v chksum=$CHKSUM -v tmpfile=$TMPFILE \
       '{ \
          if( $1 == "FEATURE" && index( $2, prodbase ) ) { \
	    $2=product \
	    $4=prodver".999" \
            $5=expire; \
            $7=code; \
            $8= "HOSTID=" tolower(hostid); \
            $9= "ck=" chksum \
          }; \
          print $0 >> tmpfile \
        }'

mv $TMPFILE $LSFILE


if ( -e $LSFILE ) then 
   echo "########################################################################"
   echo "#                                                                      #"
   echo "#                  The licence has been installed.                     #"
   echo "#                                                                      #"
   echo "########################################################################"
   echo
endif
